
    Peri

Peri is a data description library for Elixir, in the spirit of Clojure's
Plumatic Schema and Metosin's Malli. A schema is plain Elixir data: atoms
like :string, literals like {:literal, 42}, tuples, maps, keyword lists,
composed however the data demands. There is no separate DSL to learn; the
schema language is Elixir itself. Peri is data, Peri is Elixir.
Because schemas are data, they are programmable: the same definition can
validate structs, coerce string params at the boundary, generate test data,
export JSON Schema, build Ecto changesets, or render Phoenix forms.
Installation
defp deps do
  [
    {:peri, "~> 0.11.3"} # x-release-please-version
  ]
end
Quick Start
defmodule MyApp.Schemas do
  import Peri

  defschema :user, %{
    name: {:required, :string},
    age: {:integer, gte: 18},
    role: {:enum, [:admin, :user, :guest]}
  }

  defschema :search, %{
    page: {:coerce, :integer},
    tags: {:coerce, {:list, :string}, split: ","}
  }
end

MyApp.Schemas.user(%{name: "John", age: 25, role: :user})
# => {:ok, %{name: "John", age: 25, role: :user}}

# Boundary data arrives as strings; {:coerce, ...} types it.
MyApp.Schemas.search(%{"page" => "2", "tags" => "elixir,otp"})
# => {:ok, %{page: 2, tags: ["elixir", "otp"]}}
Features
	Data as schema: type expressions are plain terms (:string,
{:list, t}, {:enum, [...]}, {:literal, v}, tuples, maps) nested
however the data demands
	Boundary codecs: {:coerce, ...} with Peri.decode/3 and
Peri.encode/3 turns string params into typed data and back; targets
include constrained scalars, enums, literals, and split:-separated lists
	Validation modes: strict by default, permissive when extra keys are fine
	Errors: per-field paths, custom error: overrides, i18n via
Peri.Error.traverse_errors/2, Ecto-style rendering via
Peri.Error.humanize/1
	Schema algebra: compose with Peri.merge/2, select/2, except/2;
rewrite with Peri.walk/2; reuse with {:ref, ...}
	Integrations: Ecto changesets and custom types, Phoenix forms via
Peri.Phoenix.to_form/3, JSON Schema Draft 7 in both directions
	Data generation: StreamData-backed Peri.generate/1 with per-field
gen: overrides
	Metadata: {:meta, type, opts} attaches docs and tooling hints without
affecting validation

Documentation
	Types Reference: all types, constraints, coercion, and schema transformation
	Validation Patterns: modes, conditional and dependent validation, decoding/encoding, error handling
	Ecto Integration: changesets and custom Ecto types
	Phoenix Integration: forms and params without Ecto
	Data Generation: sample data and property testing with StreamData
	JSON Schema: Draft 7 export and import
	Refs: recursive and cross-module schema references

Why the Name "Peri"?
From the Greek "περί", meaning "around" or "about": the library wraps data
structures with descriptions of what they must conform to.


  

    Types Reference

Peri provides a comprehensive set of built-in types for schema validation.
Basic Types
	Type	Description	Example
	:any	Accepts any value	:any
	:atom	Validates atoms	:atom
	:string	Validates binary strings	:string
	:integer	Validates integers	:integer
	:float	Validates floats	:float
	:boolean	Validates booleans	:boolean
	:map	Validates maps (no content validation)	:map
	:pid	Validates process identifiers	:pid

Time Types
	Type	Description	Example
	:date	Validates %Date{}	:date
	:time	Validates %Time{}	:time
	:datetime	Validates %DateTime{}	:datetime
	:naive_datetime	Validates %NaiveDateTime{}	:naive_datetime
	:duration	Validates %Duration{}	:duration

Collection Types
	Type	Description	Example
	{:list, type}	List of elements of specified type	{:list, :string}
	{:list, type, opts}	List with constraints (:min, :max, :unique)	{:list, :string, [min: 1, max: 10, unique: true]}
	{:map, type}	Map with values of specified type	{:map, :integer}
	{:map, key_type, value_type}	Map with typed keys and values	{:map, :atom, :string}
	{:tuple, types}	Tuple with elements of specified types	{:tuple, [:float, :float]}
	{:schema, map_schema, {:additional_keys, type}}	Map with some strictly defined fields, with extras under a different type	{:schema, %{main: :string}, {:additional_keys, :integer}}

String Constraints
	Type	Description	Example
	{:string, {:regex, regex}}	String matching regex pattern	{:string, {:regex, ~r/^\w+$/}}
	{:string, {:eq, value}}	String equal to value	{:string, {:eq, "exact"}}
	{:string, {:min, length}}	String with minimum length	{:string, {:min, 3}}
	{:string, {:max, length}}	String with maximum length	{:string, {:max, 50}}
	{:string, [...options]}	String with multiple options	{:string, [min: 8, max: 64, regex: ~r/^[a-zA-Z0-9-]+$/]}

Integer Constraints
	Type	Description	Example
	{:integer, {:eq, value}}	Integer equal to value	{:integer, {:eq, 42}}
	{:integer, {:neq, value}}	Integer not equal to value	{:integer, {:neq, 0}}
	{:integer, {:gt, value}}	Integer greater than value	{:integer, {:gt, 0}}
	{:integer, {:gte, value}}	Integer greater than or equal	{:integer, {:gte, 18}}
	{:integer, {:lt, value}}	Integer less than value	{:integer, {:lt, 100}}
	{:integer, {:lte, value}}	Integer less than or equal	{:integer, {:lte, 99}}
	{:integer, {:range, {min, max}}}	Integer within range (inclusive)	{:integer, {:range, {18, 65}}}
	{:integer, {:multiple_of, n}}	Integer divisible by n	{:integer, {:multiple_of, 5}}
	{:integer, [...options]}	Integer with multiple options	{:integer, [gt: 12, lte: 96]}

Float Constraints
	Type	Description	Example
	{:float, {:eq, value}}	Float equal to value	{:float, {:eq, 3.1415}}
	{:float, {:neq, value}}	Float not equal to value	{:float, {:neq, 1.9}}
	{:float, {:gt, value}}	Float greater than value	{:float, {:gt, 1.0}}
	{:float, {:gte, value}}	Float greater than or equal	{:float, {:gte, 9.12}}
	{:float, {:lt, value}}	Float less than value	{:float, {:lt, 10.0}}
	{:float, {:lte, value}}	Float less than or equal	{:float, {:lte, 99.999}}
	{:float, {:range, {min, max}}}	Float within range (inclusive)	{:float, {:range, {8.3, 15.3}}}
	{:float, {:multiple_of, n}}	Float divisible by n	{:float, {:multiple_of, 0.25}}
	{:float, [...options]}	Float with multiple options	{:float, [gt: 1.52, lte: 29.123]}

Choice Types
	Type	Description	Example
	{:enum, choices}	Value must be one of choices	{:enum, [:admin, :user, :guest]}
	{:enum, choices, opts}	Enum with :type/:error/:gen opts	{:enum, [1, 2, 3], type: :integer}

The 3-arity form accepts a keyword list with three opts:
	:type — base Peri type that all choices must satisfy. The validator
checks the value against the base type before the membership check, and
the JSON Schema encoder surfaces it as the "type" keyword alongside
"enum" (e.g. {:enum, [1, 2, 3], type: :integer} →
%{"type" => "integer", "enum" => [1, 2, 3]}). Without :type, validation
is membership-only and JSON Schema output is a bare {"enum": [...]}.
	:error — custom error message; same form as the constraint-list error:
opt (static string or MFA returning a string).
	:gen — generator override; same form as the constraint-list gen: opt.
| {:literal, value}         | Value must exactly match     | {:literal, :active}                  |
| {:either, {type1, type2}} | Value matches either type    | {:either, {:string, :integer}}       |
| {:oneof, types}           | Value matches one of types   | {:oneof, [:string, :integer, :atom]} |

Modifiers
	Type	Description	Example
	{:required, type}	Field is required	{:required, :string}
	{type, {:default, value}}	Default value if missing	{:string, {:default, "unknown"}}
	{type, {:default, fun}}	Default from function	{:integer, {:default, &System.system_time/0}}
	{type, {:default, {m, f}}}	Default from MFA	{:string, {:default, {MyMod, :get_default}}}
	{type, {:transform, fun}}	Transform value	{:string, {:transform, &String.upcase/1}}
	{type, {:transform, {m, f}}}	Transform with MFA	{:string, {:transform, {MyMod, :clean}}}
	{:meta, type, opts}	Attach metadata, passthrough validation	{:meta, {:required, :string}, doc: "Login email", example: "a@b.io"}
	{:ref, atom}	Reference a schema in the same module	{:list, {:ref, :tree}}
	{:ref, {Mod, atom}}	Reference a schema in another module	{:ref, {OtherMod, :node}}
	{:multi, field, branches}	Tagged union dispatched on field	{:multi, :type, %{"circle" => %{r: :float}, "rect" => %{w: :float}}}

Coercion
{:coerce, source, target} converts boundary data from its source
representation into the target type during validation. The motivating case
is Phoenix params (or any form/query-string input), where everything arrives
as a string but the domain expects typed data:
defschema :search_params, %{
  page: {:coerce, :string, :integer},
  per_page: {:coerce, :string, {:integer, {:lte, 100}}},
  active: {:coerce, :string, :boolean},
  since: {:coerce, :string, :date}
}

MySchemas.search_params(%{"page" => "2", "active" => "true", "since" => "2024-03-15"})
# => {:ok, %{page: 2, active: true, since: ~D[2024-03-15]}}
The coerced value is written back into the result, and constraints on the
target are enforced after coercion ("101" above fails the {:lte, 100}
check). Values that already match the target type pass through untouched, so
already-typed data (e.g. from a JSON decoder) is a no-op.
When the source is :string it can be omitted — {:coerce, target} and
{:coerce, target, opts} are shorthand for the :string-sourced forms:
defschema :search_params, %{
  page: {:coerce, :integer},
  role: {:coerce, {:enum, [:admin, :user]}},
  tags: {:coerce, {:list, :string}, split: ","}
}
Built-in sources support :string into :integer (full parse, "12ab" is
rejected), :float ("1" becomes 1.0), :boolean ("true"/"false"
only), :atom (existing atoms only), :atom! (creates new atoms via
String.to_atom/1 — avoid on unbounded user input), :date, :time,
:naive_datetime, and :datetime (ISO 8601). Beyond scalars, :string
sources also coerce into {:enum, choices} and {:literal, value} targets
by matching the wire string against to_string/1 of each choice (so
"admin" matches :admin and "42" matches 42), and into
{:list, inner} targets when a split: opt is given:
defschema :filter_params, %{
  scores: {:coerce, {:list, :integer}, split: ","},
  ids: {:coerce, {:list, :integer}, split: [",", ";"]}
}

MySchemas.filter_params(%{"scores" => "1, 2, 3", "ids" => "4;5"})
# => {:ok, %{scores: [1, 2, 3], ids: [4, 5]}}
split: accepts a string or a list of separator strings; whitespace around
elements is trimmed and empty elements are dropped, so "" decodes to [].
Each element is coerced and validated against the inner type, and
Peri.encode/3 joins the list back with the first separator. Custom sources
are 1-arity functions or MFA tuples returning {:ok, value} or :error:
%{
  amount: {:coerce, &MyApp.Money.parse_cents/1, :integer},
  cents: {:coerce, {MyApp.Parsers, :parse_cents}, :integer}
}
{:coerce, source, target, opts} also accepts an encode: opt (function or
MFA) that customizes the reverse direction used by Peri.encode/3 — see
"Decode and encode" in pages/validation.md.
	Type	Description	Example
	{:coerce, target}	Coerce from :string to target	{:coerce, :integer}
	{:coerce, target, opts}	Shorthand with encode:/split:	{:coerce, {:list, :integer}, split: ","}
	{:coerce, source, target}	Coerce from source to target	{:coerce, :string, :integer}
	{:coerce, source, target, opts}	Coerce with a custom encode: fun	{:coerce, :string, :integer, encode: &to_string/1}
	{type, {:encode, fun}}	Apply fun only when encoding	{:string, {:encode, &String.downcase/1}}

Schema Metadata
The {:meta, type, opts} wrapper attaches documentation/tooling info to a field
without affecting validation. Blessed keys: :doc, :title, :description,
:example/:examples, :deprecated. The JSON Schema encoder also recognises
:default, :format, :pattern, :read_only, :write_only,
:content_encoding, and :content_media_type (see pages/json_schema.md).
User keys are preserved opaquely for non-encoder tooling.
defschema accepts schema-level meta opts (any non-validation key), exposed via
the generated __schema_meta__/1:
defmodule MySchemas do
  import Peri

  defschema :user, %{
    email: {:meta, {:required, :string}, doc: "Login email", example: "a@b.io"},
    age: {:meta, {:integer, gte: 0}, description: "Years"}
  }, title: "User", description: "Account holder"
end

MySchemas.__schema_meta__(:user)
# => [title: "User", description: "Account holder"]
Tagged Unions (:multi)
{:multi, dispatch_field, branches} is sugar for a discriminated union: the
value is dispatched on dispatch_field, then validated against the
matching branch schema. Errors localize to the chosen branch, so failures
read as shape.radius: invalid rather than "didn't match any of N
schemas".
%{
  shape: {:multi, :type, %{
    "circle" => %{type: {:required, :string}, radius: {:required, :float}},
    "rect"   => %{type: {:required, :string}, w: {:required, :float}, h: {:required, :float}}
  }}
}
A missing dispatch field, or a value not present in branches, surfaces
as a clear validation error listing the known tags. JSON Schema export
emits oneOf plus a discriminator annotation; data generation samples
a branch and merges the dispatch tag into the generated value.
For untagged "any of these types" semantics, use {:oneof, types} instead.
Custom Validation
	Type	Description	Example
	{:custom, callback}	Custom validation function	{:custom, &validate_email/1}
	{:custom, {mod, fun}}	Custom validation MFA	{:custom, {MyMod, :validate}}
	{:custom, {mod, fun, args}}	Custom validation with args	{:custom, {MyMod, :validate, []}}

Custom Error Messages
Override the default error template for any field using the error: opt in its
options list. Accepted forms: a static string, or an MFA {mod, fun, args} that
receives the %Peri.Error{} prepended to args and returns a string.
	Form	Description	Example
	{type, [..., error: msg]}	Static replacement message	{:integer, gte: 18, error: "must be adult"}
	{:required, type, [error: msg]}	Static message on a required field	{:required, :string, [error: "needed"]}
	{:required, type, [error: {mod, fun, args}]}	MFA receives %Peri.Error{} and returns string	{:required, :string, [error: {Msgs, :email, []}]}

defmodule MyApp.Schemas do
  import Peri

  defmodule Msgs do
    def email_msg(%Peri.Error{content: ctx}), do: "email is invalid (#{inspect(ctx)})"
  end

  defschema :user, %{
    age:   {:integer, gte: 18, error: "must be adult"},
    email: {:required, :string, [error: {Msgs, :email_msg, []}]}
  }
end
For i18n, post-process the error list with Peri.Error.traverse_errors/2,
which walks nested errors and replaces each leaf message with the callback's
return value:
{:error, errors} = MyApp.Schemas.user(%{age: 10})

Peri.Error.traverse_errors(errors, fn err ->
  Gettext.dgettext(MyAppWeb.Gettext, "errors", err.message, err.content || %{})
end)
The MFA / static override fires first; traverse_errors/2 runs over whatever
message remains (overridden or default). No hard dependency on Gettext —
the callback is opaque.
Schema Transformation (Peri.walk/2)
Peri.walk/2 is a depth-first rewrite over a schema tree — a building block
for derivations like "make every field optional" or "drop internal-only
fields from a public DTO". The callback is invoked on every subtree, and its
contract depends on context:
	Position	Callback receives	Valid returns
	Map / keyword schema entry	{:field, k, v}	{:cont, {:field, k', v'}} or :drop
	Any other subtree (type expression)	the node itself	{:cont, new_node} (:drop raises here)

Map keys, constraint option lists (e.g. [gte: 18, error: "..."]), :enum
members, :literal values, :ref names, :multi tags, callbacks, and
transforms are not visited — only sub-schemas and field entries are.
Make every field optional
Peri.walk(schema, fn
  {:required, t} -> {:cont, t}
  {:required, t, _opts} -> {:cont, t}
  other -> {:cont, other}
end)
Strip private fields from a DTO
Peri.walk(internal_schema, fn
  {:field, k, _v} when k in [:internal_id, :secret_token] -> :drop
  other -> {:cont, other}
end)
Rename a field
Peri.walk(schema, fn
  {:field, :email, v} -> {:cont, {:field, :login, v}}
  other -> {:cont, other}
end)
Compose with other tools
The result of walk/2 is a plain Peri schema, ready to feed to
Peri.validate/2, Peri.to_json_schema/1, Peri.generate/1, or another
walker pass.
Composing schemas
Schemas are plain maps, so Peri.merge/2, Peri.select/2, and
Peri.except/2 build new schemas from existing ones without redeclaring
fields. All three return {:ok, schema} after checking the result with
Peri.validate_schema/1.
user = %{
  name: {:required, :string},
  email: {:required, :string},
  password_hash: :string
}

# merge: deep merge, right side wins on conflicts
{:ok, admin} = Peri.merge(user, %{role: {:enum, [:admin, :member]}})

# select: keep a subset for a public DTO
{:ok, public_user} = Peri.select(user, [:name, :email])

# except: drop sensitive fields
{:ok, safe_user} = Peri.except(user, [:password_hash])
merge/2 merges nested map schemas recursively; type tuples and directives
are never merged structurally, the right side wins. select/2 and
except/2 ignore keys that are not present in the schema.
Generator Overrides (gen: opt)
Constrained types like {:string, {:regex, …}} or {:integer, gt: 1_000_000}
can be slow to generate via Peri.generate/1 because StreamData's default
strategy is rejection sampling. Supply a gen: opt with a custom generator
to skip rejection altogether:
	Form	Description
	gen: {Mod, :fun, args}	MFA returning a %StreamData{}
	gen: {Mod, :fun}	MF (zero args), same return contract
	gen: fn -> StreamData.… end	0-arity function, same contract

Accepted positions:
%{
  # multi-options on a constrained primitive
  age:    {:integer, gte: 18, lte: 120, gen: {MyApp.Gens, :age, []}},

  # required wrapper
  login:  {:required, :string, [gen: {MyApp.Gens, :login}]},

  # meta wrapper (combines with docs/examples)
  email:  {:meta, {:required, {:string, {:regex, ~r/@/}}},
                  doc: "Login email",
                  gen: {MyApp.Gens, :email, []}}
}
Without an override, Peri.generate/1 falls back to chaining
StreamData.filter/2 for each constraint.
Simple User Schema
%{
  name: {:required, :string},
  age: {:integer, {:gte, 0}},
  email: {:required, {:string, {:regex, ~r/@/}}},
  role: {:enum, [:admin, :user]}
}
Complex Nested Schema
%{
  user: %{
    profile: {:required, %{
      name: {:required, :string},
      bio: {:string, {:max, 500}}
    }},
    preferences: {:map, :string, :boolean},
    tags: {:list, :string}
  }
}


  

    Validation Patterns

Advanced validation patterns for dynamic and context-aware schemas.
Validation Modes
Peri supports two validation modes to control how extra fields are handled:
Strict Mode (Default)
By default, Peri operates in strict mode, which filters out any fields not defined in the schema:
schema = %{
  name: :string,
  age: :integer
}

data = %{name: "John", age: 30, extra: "field"}

{:ok, result} = Peri.validate(schema, data)
# result => %{name: "John", age: 30}
Permissive Mode
Permissive mode preserves all fields from the input data, even those not defined in the schema:
{:ok, result} = Peri.validate(schema, data, mode: :permissive)
# result => %{name: "John", age: 30, extra: "field"}
Using Permissive Mode with defschema
You can define schemas that always use permissive mode:
defmodule MySchemas do
  import Peri

  # Strict mode (default)
  defschema :user_strict, %{
    name: :string,
    email: {:required, :string}
  }

  # Permissive mode
  defschema :user_permissive, %{
    name: :string,
    email: {:required, :string}
  }, mode: :permissive
end

data = %{name: "John", email: "john@example.com", role: "admin"}

# Strict mode filters out 'role'
{:ok, strict} = MySchemas.user_strict(data)
# strict => %{name: "John", email: "john@example.com"}

# Permissive mode keeps 'role'
{:ok, permissive} = MySchemas.user_permissive(data)
# permissive => %{name: "John", email: "john@example.com", role: "admin"}
Use Cases for Permissive Mode
Permissive mode is useful when:
	Building API gateways that need to forward extra fields
	Implementing progressive validation in layers
	Working with evolving data structures where new fields may be added
	Creating middleware that validates known fields but passes through metadata

Note: Fields not defined in the schema are not validated, they are simply passed through unchanged.
Conditional Validation
Use :cond to validate fields based on runtime conditions.
defmodule UserSchema do
  import Peri

  defschema :registration, %{
    name: {:required, :string},
    is_premium: {:required, :boolean},
    # Only require payment info if premium
    payment_info: {:cond, & &1.is_premium, {:required, :string}, nil}
  }
end
Dependent Validation
Two forms, with different contracts:
	{:dependent, field, condition, type} - condition is called with
(value, dependent_value) and must return :ok or
{:error, message, info}. On :ok, the value is validated against type.
	{:dependent, callback} - callback (fun/1, fun/2, or MFA) must return
{:ok, type} or {:error, message, info}. On {:ok, type} the field is
validated against type; {:ok, nil} means the field must be absent. On
{:error, message, info} the field fails with that error directly.

Returning anything else (e.g. the bare type without the :ok wrapper) is a
contract breach and fails validation with an error naming the field.
Single Field Dependency
Validate a field based on another field's value:
defmodule AuthSchema do
  import Peri

  defschema :user, %{
    password: {:required, :string},
    password_confirmation: {:dependent, :password, &match_passwords/2, :string}
  }

  defp match_passwords(password, password), do: :ok
  defp match_passwords(_, _), do: {:error, "passwords must match", []}
end
Dynamic Type via Callback
Compute the field's type from the rest of the data. The callback receives the
root data (fun/1), or the current element and the root data (fun/2), and
returns the type to validate against:
defmodule ProfileSchema do
  import Peri

  defschema :user_profile, %{
    contact_type: {:required, {:enum, [:email, :phone, :both]}},
    email: {:string, {:regex, ~r/@/}},
    phone: :string,
    contact_info: {:dependent, &validate_contact/1}
  }

  defp validate_contact(%{contact_type: :email}) do
    {:ok, {:required, %{email: {:required, :string}}}}
  end

  defp validate_contact(%{contact_type: :phone}) do
    {:ok, {:required, %{phone: {:required, :string}}}}
  end

  defp validate_contact(%{contact_type: :both}) do
    {:ok, {:required, %{
      email: {:required, :string},
      phone: {:required, :string}
    }}}
  end
end
MFA callbacks work the same way - {:dependent, {Mod, fun}} calls
Mod.fun(root) (or Mod.fun(current, root) if arity 2 is exported), and
{:dependent, {Mod, fun, args}} calls Mod.fun(root, args...):
defschema :attachment, %{
  kind: {:required, {:enum, [:avatar, :document]}},
  payload: {:dependent, {__MODULE__, :payload_type}}
}

def payload_type(%{kind: :avatar}), do: {:ok, {:required, :string}}
def payload_type(_), do: {:ok, nil}
Custom Validation
Simple Custom Validator
defmodule ProductSchema do
  import Peri

  defschema :product, %{
    price: {:custom, &validate_price/1}
  }

  defp validate_price(price) when price > 0, do: :ok
  defp validate_price(price), do: {:error, "price must be positive, got %{price}", [price: price]}
end
MFA Custom Validators
defmodule OrderSchema do
  import Peri

  defschema :order, %{
    items: {:list, {:custom, {__MODULE__, :validate_item, [:in_stock]}}},
    total: {:custom, {Calculator, :validate_total}}
  }

  def validate_item(item, :in_stock) do
    if item.stock > 0 do
      :ok
    else
      {:error, "item %{name} is out of stock", [name: item.name]}
    end
  end
end
Callback Arities
1-Arity Callbacks (Root Data)
Receives the entire root data structure:
%{
  user_type: :premium,
  features: {:cond, fn data -> data.user_type == :premium end,
             {:list, :string},
             {:literal, []}}
}
2-Arity Callbacks (Current + Root)
Receives current context and root data - useful for lists:
defmodule ItemSchema do
  import Peri

  defschema :item, %{
    type: {:required, :string},
    # Validates based on current item's type, not parent data
    value: {:dependent, fn current, _root ->
      case current.type do
        "number" -> {:ok, :integer}
        "text" -> {:ok, :string}
        _ -> {:ok, :any}
      end
    end}
  }

  defschema :collection, %{
    items: {:list, get_schema(:item)}
  }
end

# Each item validates independently
data = %{
  items: [
    %{type: "number", value: 42},
    %{type: "text", value: "hello"}
  ]
}
Schema Composition
Reusable Schemas
defmodule BaseSchemas do
  import Peri

  defschema :address, %{
    street: {:required, :string},
    city: {:required, :string},
    zip: {:string, {:regex, ~r/^\d{5}$/}}
  }

  defschema :person, %{
    name: {:required, :string},
    address: get_schema(:address)
  }

  defschema :company, %{
    name: {:required, :string},
    headquarters: get_schema(:address),
    employees: {:list, get_schema(:person)}
  }
end
Schema Merging
defmodule UserSchemas do
  import Peri

  defschema :base_user, %{
    name: {:required, :string},
    email: {:required, :string}
  }

  defschema :admin_user, Map.merge(get_schema(:base_user), %{
    permissions: {:required, {:list, :string}},
    last_login: :datetime
  })
end
Error Context
Custom validators can provide detailed error context:
defp validate_complex_rule(value) do
  case expensive_validation(value) do
    :ok -> :ok
    {:error, reason} ->
      {:error, "validation failed: %{reason} for value %{value}",
       [reason: reason, value: inspect(value)]}
  end
end
Decode and Encode
Coercion is a schema directive, so decoding wire data is just validation:
Peri.decode/3 is an alias of Peri.validate/3 that reads naturally at the
boundary. Peri.encode/3 runs the same schema in the opposite direction — it
validates the data against the target types, then produces the wire
representation:
schema = %{
  "page" => {:coerce, :string, :integer},
  "since" => {:coerce, :string, :date}
}

{:ok, decoded} = Peri.decode(schema, %{"page" => "2", "since" => "2024-03-15"})
# => {:ok, %{"page" => 2, "since" => ~D[2024-03-15]}}

{:ok, wire} = Peri.encode(schema, decoded)
# => {:ok, %{"page" => "2", "since" => "2024-03-15"}}
On encode, built-in :string sources render with to_string/1
(to_iso8601/1 for date/time structs). A coerce directive may carry an
encode: opt to customize the reverse, and custom function/MFA sources
without an encode: opt pass the validated value through unchanged.
Two related directives round out the codec story:
	{type, {:encode, fun}} applies fun (or an MFA) to the value during
Peri.encode/3 only; it is inert under validate/3 and decode/3.
	{type, {:transform, fun}} is skipped during Peri.encode/3 — transforms
are decode-only.

Note that Peri.encode/3 still validates: encoding data that does not match
the target types returns the usual {:error, errors} tuple.
Rendering Errors
Peri.Error.humanize/1 converts an error (or list of errors) into a
nested, data-shaped map of messages, mirroring
Ecto.Changeset.traverse_errors/2 output. Integer path segments become
integer keys (list indices), and multiple errors at the same path append
to the message list:
{:error, errors} = MySchemas.user(%{addresses: [%{street: "x"}]})

Peri.Error.humanize(errors)
# => %{addresses: %{0 => %{street: ["is too short"]}}}
This shape drops straight into API error payloads and form rendering.
Because humanize/1 reads each leaf's final message verbatim, it composes
with traverse_errors/2: translate first, then humanize.
Errors without a path come from top-level scalar validations
(Peri.validate(:string, 5)); with no field to nest under, they humanize
to a bare list of messages.
Missing Key Suggestions
When a required field is missing but the data contains a key that looks
like a typo of it (Jaro distance above 0.8, compared across atom and
string key forms), the error message gains a suggestion and the error
content carries it under :did_you_mean:
{:error, [error]} = Peri.validate(%{email: {:required, :string}}, %{emial: "a@b.c"})

error.message
# => "is required, expected type of :string did you mean :emial?"
error.content[:did_you_mean]
# => :emial
This works in both strict and permissive modes, including inside nested
schemas and list elements. A static or MFA error: override still
replaces the message; the :did_you_mean content remains available.


  

    Ecto Integration

Convert Peri schemas to Ecto schemaless changesets for data validation.
Basic Usage
defmodule UserValidator do
  import Peri

  defschema :user, %{
    name: {:required, :string},
    age: {:integer, {:gte, 18}},
    email: {:required, {:string, {:regex, ~r/@/}}},
    role: {:enum, [:admin, :user]}
  }

  def validate_user(attrs) do
    # Convert Peri schema to Ecto changeset
    Peri.to_changeset!(get_schema(:user), attrs)
  end
end

# Usage
attrs = %{"name" => "John", "age" => 25, "email" => "john@example.com"}
changeset = UserValidator.validate_user(attrs)
Type Mapping
Peri types are automatically mapped to appropriate Ecto types:
	Peri Type	Ecto Type	Notes
	:string	:string	Direct mapping
	:integer	:integer	Direct mapping
	:float	:float	Direct mapping
	:boolean	:boolean	Direct mapping
	:date	:date	Direct mapping
	:datetime	:utc_datetime	UTC datetime
	:naive_datetime	:naive_datetime	Direct mapping
	{:enum, choices}	Custom validation	Validates against choices
	{:list, type}	{:array, type}	Array of specified type
	:any	Custom type	Allows any value
	:atom	Custom type	Validates atoms
	{:tuple, types}	Custom type	Validates tuple structure

Constraint Mapping
Peri constraints are converted to Ecto validations:
# Peri schema
%{
  name: {:string, {:min, 2}},
  age: {:integer, {:range, {18, 65}}},
  email: {:string, {:regex, ~r/@/}}
}

# Equivalent Ecto validations applied
changeset
|> validate_length(:name, min: 2)
|> validate_number(:age, greater_than_or_equal_to: 18, less_than_or_equal_to: 65)
|> validate_format(:email, ~r/@/)
Nested Validation
defmodule ProfileValidator do
  import Peri

  defschema :address, %{
    street: {:required, :string},
    city: {:required, :string},
    zip: {:string, {:regex, ~r/^\d{5}$/}}
  }

  defschema :user, %{
    name: {:required, :string},
    address: {:required, get_schema(:address)},
    tags: {:list, :string}
  }

  def validate_user(attrs) do
    changeset = Peri.to_changeset!(get_schema(:user), attrs)
    # Nested validation happens automatically
    case changeset.valid? do
      true -> {:ok, Ecto.Changeset.apply_changes(changeset)}
      false -> {:error, changeset}
    end
  end
end

# Usage with nested data
attrs = %{
  "name" => "John",
  "address" => %{
    "street" => "123 Main St",
    "city" => "Anytown",
    "zip" => "12345"
  },
  "tags" => ["developer", "elixir"]
}

case ProfileValidator.validate_user(attrs) do
  {:ok, validated_data} -> IO.puts("Valid!")
  {:error, changeset} -> IO.inspect(changeset.errors)
end
Custom Types
Peri provides custom Ecto types for advanced validation:
# Available custom types
Peri.Ecto.Type.Any      # Accepts any value
Peri.Ecto.Type.Atom     # Validates atoms
Peri.Ecto.Type.Tuple    # Validates tuples
Peri.Ecto.Type.Either   # Union types
Peri.Ecto.Type.OneOf    # Multiple choice types
Error Handling
Peri validation errors are automatically converted to Ecto changeset errors:
attrs = %{"name" => "", "age" => 15}
changeset = Peri.to_changeset!(schema, attrs)

# Access errors like normal Ecto changeset
changeset.errors
# [
#   name: {"can't be blank", [validation: :required]},
#   age: {"must be greater than or equal to %{number}",
#         [validation: :number, kind: :greater_than_or_equal_to, number: 18]}
# ]

# Check if valid
if changeset.valid? do
  data = Ecto.Changeset.apply_changes(changeset)
  {:ok, data}
else
  {:error, changeset}
end
Working with Phoenix
Perfect for Phoenix controller validation:
defmodule MyAppWeb.UserController do
  use MyAppWeb, :controller
  import Peri

  defschema :user_params, %{
    name: {:required, :string},
    email: {:required, {:string, {:regex, ~r/@/}}},
    age: {:integer, {:gte, 18}}
  }

  def create(conn, params) do
    changeset = Peri.to_changeset!(get_schema(:user_params), params)

    if changeset.valid? do
      user_data = Ecto.Changeset.apply_changes(changeset)
      # Process valid data...
      json(conn, %{success: true, user: user_data})
    else
      conn
      |> put_status(:unprocessable_entity)
      |> json(%{errors: translate_errors(changeset)})
    end
  end

  defp translate_errors(changeset) do
    Ecto.Changeset.traverse_errors(changeset, fn {msg, opts} ->
      Regex.replace(~r"%{(\w+)}", msg, fn _, key ->
        opts |> Keyword.get(String.to_existing_atom(key), key) |> to_string()
      end)
    end)
  end
end
Benefits
	Familiar API: Uses standard Ecto changeset interface
	Rich Validation: Access to all Peri's validation features
	Error Consistency: Standard Ecto error format
	Phoenix Ready: Works seamlessly with Phoenix forms and APIs
	Composable: Combine with other Ecto changeset operations



  

    Phoenix Integration

Validate params with a Peri schema and render Phoenix/LiveView forms without
Ecto. Peri.Phoenix.to_form/3 decodes and validates params, wraps the result
in a Peri.Form struct, and converts it into a Phoenix.HTML.Form through
the Phoenix.HTML.FormData protocol, so Phoenix.Component.form/1 and the
<.input> component work out of the box.
This integration is compiled only when the optional phoenix_html dependency
is present:
# mix.exs
{:phoenix_html, "~> 4.1"}
Basic Usage
@schema %{
  name: {:required, :string},
  email: {:required, {:string, {:regex, ~r/@/}}},
  age: {:coerce, :string, {:integer, {:gte, 18}}}
}

# Valid params: the form carries the validated data and no errors
Peri.Phoenix.to_form(@schema, %{"name" => "Jane", "email" => "jane@x.com", "age" => "27"})

# Invalid params: errors in changeset format, action set to :validate
form = Peri.Phoenix.to_form(@schema, %{"age" => "17"})
form.errors
# [name: {"is required, expected type of :string", []},
#  email: {"is required, expected type of :string", []},
#  age: {"should be greater then or equal to 18", []}]
Because params flow through Peri.decode/3, the {:coerce, :string, target}
directive converts string params into typed data: "27" validates as the
integer 27 and constraint failures like "17" against {:gte, 18} are
reported on the typed value.
Options
to_form/3 accepts the shared Phoenix.HTML.FormData options plus :mode:
	:as - form name, defaults to "peri"
	:id - form id, defaults to the name
	:action - form action (defaults to :validate when validation fails)
	:mode - validation mode forwarded to Peri.decode/3 (:strict by
default, :permissive keeps unknown fields)

LiveView Round Trip
defmodule MyAppWeb.SignupLive do
  use MyAppWeb, :live_view

  @schema %{
    name: {:required, :string},
    email: {:required, {:string, {:regex, ~r/@/}}},
    age: {:coerce, :string, {:integer, {:gte, 18}}}
  }

  def mount(_params, _session, socket) do
    {:ok, assign(socket, form: Peri.Phoenix.to_form(@schema))}
  end

  def handle_event("validate", %{"peri" => params}, socket) do
    {:noreply, assign(socket, form: Peri.Phoenix.to_form(@schema, params))}
  end

  def handle_event("save", %{"peri" => params}, socket) do
    case Peri.decode(@schema, params) do
      {:ok, data} ->
        # persist the typed data, redirect, ...
        {:noreply, socket}

      {:error, _errors} ->
        {:noreply, assign(socket, form: Peri.Phoenix.to_form(@schema, params))}
    end
  end

  def render(assigns) do
    ~H"""
    <.form for={@form} phx-change="validate" phx-submit="save">
      <.input field={@form[:name]} label="Name" />
      <.input field={@form[:email]} label="Email" />
      <.input field={@form[:age]} type="number" label="Age" />
      <button>Save</button>
    </.form>
    """
  end
end
The update path also accepts the form's source struct directly:
Peri.Phoenix.to_form(form.source, new_params) revalidates against the
stored schema.
HTML5 validations come from the schema: {:required, type} fields render
required, and {:string, {:min, n}} / {:string, {:max, n}} render
minlength / maxlength.
Nested Schemas and inputs_for
Nested map schemas work with Phoenix.HTML.FormData.to_form/4 (what
inputs_for calls under the hood), and nested errors surface in the nested
form:
@schema %{
  name: {:required, :string},
  address: %{
    street: {:required, :string},
    city: :string
  }
}

form = Peri.Phoenix.to_form(@schema, %{"name" => "Jane", "address" => %{}})
[address_form] = Phoenix.HTML.FormData.to_form(form.source, form, :address, [])
address_form[:street].errors
# [{"is required, expected type of :string", []}]
List-of-map schemas ({:list, %{...}}) expand to one form per entry, keyed
by index (peri[tags][0], peri[tags][1], ...), reading values from params
first and falling back to validated data.
Caveats
	No changeset parity. Peri.Form carries validated data, raw params,
and errors; it does not track changes, touch state, or apply/rollback
semantics. If you need those, use the Ecto integration instead.
	List element errors are not indexed. Peri currently reports errors
inside list elements at the field level (e.g. [:tags, :label]) rather
than per index ([:tags, 0, :label]), so per-entry errors for
list-of-map schemas cannot be attributed to a specific form entry. Nested
map errors are fully supported.
	Failed validation discards data. When validation fails the form keeps
only the raw params (which is what inputs re-render from), not a partially
validated result.



  

    Data Generation

Generate sample data based on your Peri schemas using StreamData.
Setup
Add StreamData to your dependencies:
# mix.exs
defp deps do
  [
    {:peri, "~> 0.11.3"}, # x-release-please-version
    {:stream_data, "~> 1.0", only: [:test, :dev]}
  ]
end
Basic Usage
defmodule UserSchema do
  import Peri

  defschema :user, %{
    name: :string,
    age: {:integer, {:gte, 18}},
    active: :boolean
  }
end

# Generate sample data
sample_data = Peri.generate(UserSchema.get_schema(:user))
Enum.take(sample_data, 3)
# [
#   %{name: "abc", age: 23, active: true},
#   %{name: "xyz", age: 45, active: false},
#   %{name: "def", age: 67, active: true}
# ]
Constraint-Aware Generation
Generators respect Peri constraints:
schema = %{
  username: {:string, {:regex, ~r/^[a-z]+$/}},
  score: {:integer, {:range, {0, 100}}},
  role: {:enum, [:admin, :user, :guest]},
  tags: {:list, :string}
}

# Generated data will match constraints
samples = Peri.generate(schema) |> Enum.take(5)
# All usernames will be lowercase letters only
# All scores will be 0-100
# All roles will be from the enum
Property-Based Testing
Perfect for property-based testing with ExUnit:
defmodule UserTest do
  use ExUnit.Case
  use ExUnitProperties
  import Peri

  defschema :user, %{
    name: {:required, :string},
    age: {:integer, {:gte, 0, :lte, 120}},
    email: {:string, {:regex, ~r/@/}}
  }

  property "user validation always succeeds for generated data" do
    check all user_data <- Peri.generate(get_schema(:user)) do
      assert {:ok, _} = Peri.validate(get_schema(:user), user_data)
    end
  end

  property "age is always within bounds" do
    check all %{age: age} <- Peri.generate(get_schema(:user)) do
      assert age >= 0 and age <= 120
    end
  end
end
Complex Data Structures
Generate nested and complex data:
defmodule ComplexSchema do
  import Peri

  defschema :address, %{
    street: :string,
    city: :string,
    zip: {:string, {:regex, ~r/^\d{5}$/}}
  }

  defschema :person, %{
    name: {:required, :string},
    addresses: {:list, get_schema(:address)},
    preferences: {:map, :string, :boolean},
    coordinates: {:tuple, [:float, :float]}
  }
end

# Generates fully nested structures
sample = Peri.generate(ComplexSchema.get_schema(:person)) |> Enum.take(1) |> hd()
# %{
#   name: "John",
#   addresses: [
#     %{street: "123 Main", city: "Boston", zip: "02101"},
#     %{street: "456 Oak", city: "Salem", zip: "01970"}
#   ],
#   preferences: %{"dark_mode" => true, "notifications" => false},
#   coordinates: {42.3601, -71.0589}
# }
Custom Generators
For :custom types, provide your own generators:
defmodule CustomSchema do
  import Peri

  defschema :product, %{
    id: {:custom, &validate_uuid/1},
    price: {:custom, &validate_price/1}
  }

  defp validate_uuid(uuid) when is_binary(uuid) do
    # UUID validation logic
    :ok
  end

  defp validate_price(price) when is_number(price) and price > 0, do: :ok
  defp validate_price(_), do: {:error, "invalid price", []}
end

# Note: Custom generators need to be implemented separately
# This is a limitation - custom types require manual generator setup
Seeding Development Data
Use for development database seeding:
defmodule MyApp.Seeds do
  import Peri

  defschema :user_seed, %{
    name: {:string, {:min, 3}},
    email: {:string, {:regex, ~r/.+@.+\..+/}},
    role: {:enum, [:admin, :user]},
    active: {:boolean, {:default, true}}
  }

  def seed_users(count \\ 50) do
    Peri.generate(get_schema(:user_seed))
    |> Enum.take(count)
    |> Enum.each(fn user_data ->
      MyApp.Users.create_user(user_data)
    end)
  end
end

# Run in seeds.exs or IEx
MyApp.Seeds.seed_users(100)
API Testing
Generate test data for API endpoints:
defmodule MyAppWeb.UserControllerTest do
  use MyAppWeb.ConnCase
  use ExUnitProperties
  import Peri

  defschema :user_request, %{
    name: {:required, :string},
    email: {:required, {:string, {:regex, ~r/@/}}},
    age: {:integer, {:gte, 18}}
  }

  property "POST /users accepts valid user data" do
    check all user_params <- Peri.generate(get_schema(:user_request)) do
      conn = post(build_conn(), "/users", user_params)
      assert json_response(conn, 201)
    end
  end
end
Custom Generators (gen: opt)
Constrained types fall back to rejection sampling, which can be slow when
the accepting domain is narrow (e.g. {:integer, gt: 1_000_000} or a regex
that few random strings satisfy). Provide a gen: opt that returns a
%StreamData{} directly to skip rejection entirely.
defmodule MyApp.Gens do
  def adult_age, do: StreamData.integer(18..120)
  def email_with_prefix(prefix), do: StreamData.constant(prefix <> "@example.com")
end

%{
  age:   {:integer, gte: 18, lte: 120, gen: {MyApp.Gens, :adult_age, []}},
  login: {:required, :string, [gen: {MyApp.Gens, :fixed_login}]},
  email: {:meta, :string,
                 doc: "Login email",
                 gen: {MyApp.Gens, :email_with_prefix, ["root"]}}
}
Accepted callable forms: {mod, fun, args} (MFA), {mod, fun} (zero args),
or a 0-arity function. Without a gen: opt, the generator chains
StreamData.filter/2 for each constraint — correct, but slow on tight
domains.
Limitations
	Custom Types: Custom validation types need manual generator implementation
	Performance: Large data generation may be slow for complex nested structures
	Dependencies: Requires StreamData dependency for generation features

Best Practices
	Use generation primarily for testing and development seeding
	Keep generated data size reasonable for performance
	Combine with ExUnitProperties for comprehensive property-based testing
	Use constraints to ensure realistic data generation



  

    JSON Schema

Peri can convert schemas to and from JSON Schema (Draft 7) maps.
Encoding
schema = %{
  name: {:required, :string},
  age: {:integer, gte: 0},
  email: {:meta, {:required, :string}, description: "Login email", example: "a@b.io"}
}

Peri.to_json_schema(schema)
# => %{
#   "type" => "object",
#   "properties" => %{
#     "name" => %{"type" => "string"},
#     "age" => %{"type" => "integer", "minimum" => 0},
#     "email" => %{
#       "type" => "string",
#       "description" => "Login email",
#       "examples" => ["a@b.io"]
#     }
#   },
#   "required" => ["name", "email"]
# }
Metadata
{:meta, type, opts} annotations are read during encoding. Recognised keys map
to JSON Schema annotation/format keywords:
	Peri meta key	JSON Schema key
	:title	title
	:description	description
	:example	examples (wrapped in array)
	:examples	examples
	:deprecated	deprecated
	:default	default
	:format	format
	:pattern	pattern
	:read_only	readOnly
	:write_only	writeOnly
	:content_encoding	contentEncoding
	:content_media_type	contentMediaType

Unknown keys are dropped from the encoded schema (they remain available to
other tooling that reads :meta directly).
Type mapping
	Peri	JSON Schema
	:string, :integer, :float, :boolean	"type" keyword
	:date, :time, :datetime	"string" + "format"
	{:list, t}	"array" + "items"
	{:map, t}, {:map, k, v}	"object" + "additionalProperties"
	{:tuple, ts}	fixed-length "array"
	{:enum, vs}	"enum"
	{:enum, vs, type: t}	"type" of t + "enum"
	{:literal, v}	"const"
	{:either, {a, b}}, {:oneof, ts}	"oneOf"
	{:required, t}	adds key to parent "required"
	{type, gte: n}	"minimum"
	{type, gt: n}	"exclusiveMinimum"
	{:string, {:regex, r}}	"pattern"

Dynamic types
:dependent, :cond, :custom, and {type, {:transform, _}} cannot be
expressed statically. Use :on_unsupported:
Peri.to_json_schema(schema, on_unsupported: :raise)
	:omit (default) — emit %{} (true schema)
	:true_schema — same as :omit
	:raise — raise Peri.JSONSchema.Encoder.UnsupportedTypeError

Excluding annotation keys
Pass :exclude_meta_keys with a list of meta keywords to drop from the output.
Useful when the consumer-facing schema should not surface validation defaults:
Peri.to_json_schema(
  %{count: {:integer, {:default, 0}}},
  exclude_meta_keys: [:default]
)
# => %{
#   "type" => "object",
#   "properties" => %{"count" => %{"type" => "integer"}}
# }
Both the direct {type, {:default, v}} form and the {:meta, type, default: v}
form honour the exclusion. Any subset of the meta vocabulary above is accepted.
Typed enums
{:enum, choices, type: t} surfaces the base type alongside the "enum"
keyword, producing schemas consumers can validate against:
Peri.to_json_schema({:enum, [1, 2, 3], type: :integer})
# => %{"type" => "integer", "enum" => [1, 2, 3]}
Decoding is symmetric: a JSON Schema with both "type" and "enum" round-trips
to {:enum, values, type: base}.
Decoding
{:ok, schema} =
  Peri.from_json_schema(%{
    "type" => "object",
    "properties" => %{"name" => %{"type" => "string"}},
    "required" => ["name"]
  })

# schema => %{name: {:required, :string}}
from_json_schema/1 runs Peri.validate_schema/1 on the result, returning
{:error, errors} if the JSON Schema cannot be expressed as a valid Peri
schema.


  

    Refs

The :ref directive lets schemas reference other named schemas, enabling
recursive structures (trees, ASTs, linked lists) and cross-module reuse.
Local refs
Inside a defschema, {:ref, atom} resolves to the same module's
get_schema/1 callback. The defschema macro rewrites local refs at
expansion to {:ref, {__MODULE__, atom}}, so authors don't have to spell
out the module name.
defmodule Trees do
  import Peri

  defschema :tree, %{
    value: {:required, :integer},
    children: {:list, {:ref, :tree}}
  }
end

Trees.tree(%{value: 1, children: [%{value: 2, children: []}]})
# => {:ok, %{value: 1, children: [%{value: 2, children: []}]}}
Cross-module refs
Use {:ref, {Mod, atom}} to reference a schema from another module. The
target module must export get_schema/1, which defschema provides
automatically.
defmodule MySchemas.Cross do
  import Peri

  defschema :graph, %{
    root: {:ref, {Trees, :tree}},
    related: {:list, {:ref, {Other, :node}}}
  }
end
Cycle protection
Recursive schemas terminate when the data terminates. Pathological inputs
(infinite or near-infinite nesting) are stopped by a runtime depth limit
of 64 ref resolutions, surfaced as a validation error rather than a stack
overflow.
Refs in :oneof / :either
Inside polymorphic types, refs keep error messages legible. A ref renders
as its schema name, while an inlined get_schema/1 map renders as a
truncated key summary:
%{body: {:oneof, [{:ref, {MyApp.Schemas, :lexicon_record}},
                  {:ref, {MyApp.Schemas, :lexicon_query}}]}}
# failure => "expected one of MyApp.Schemas.lexicon_record or
#            MyApp.Schemas.lexicon_query, got: ..."

%{body: {:oneof, [MyApp.Schemas.get_schema(:lexicon_record), ...]}}
# failure => "expected one of %{keys: [:collection, :rkey]} or ..., got: ..."
Integrations
	JSON Schema export — refs emit $ref + $defs entries. The def
body is the inlined target schema; cycles bottom out at the $ref
reference.
	Ecto — refs degrade to :map on the changeset side. Peri.validate/2
still resolves the ref properly; the changeset path treats it opaquely.
	StreamData — generation expands the ref up to 5 levels deep, then
yields nil to terminate. Sufficient for property tests of recursive
data; not a substitute for hand-written generators on deep structures.



  

    
Peri 
    



      
Peri is a data description library for Elixir, in the spirit of Clojure's
Plumatic Schema and Metosin's Malli. A schema is plain Elixir data: atoms
like :string, literals like {:literal, 42}, tuples, maps, keyword lists,
composed however the data demands. There is no separate DSL to learn; the
schema language is Elixir itself. Peri is data, Peri is Elixir.
Because schemas are data, they are programmable: the same definition can
validate structs, coerce string params at the boundary, generate test data,
export JSON Schema, build Ecto changesets, or render Phoenix forms.
Installation
defp deps do
  [
    {:peri, "~> 0.11.3"} # x-release-please-version
  ]
end
Quick Start
defmodule MyApp.Schemas do
  import Peri

  defschema :user, %{
    name: {:required, :string},
    age: {:integer, gte: 18},
    role: {:enum, [:admin, :user, :guest]}
  }

  defschema :search, %{
    page: {:coerce, :integer},
    tags: {:coerce, {:list, :string}, split: ","}
  }
end

MyApp.Schemas.user(%{name: "John", age: 25, role: :user})
# => {:ok, %{name: "John", age: 25, role: :user}}

# Boundary data arrives as strings; {:coerce, ...} types it.
MyApp.Schemas.search(%{"page" => "2", "tags" => "elixir,otp"})
# => {:ok, %{page: 2, tags: ["elixir", "otp"]}}
Guides
	Schema types and directives: the full type vocabulary,
basic and time types, collections, enums, literals, constraints,
coercion/encoding, {:meta, ...}, custom error messages, schema
transformation with Peri.walk/2
	Validation semantics: strict/permissive modes,
:cond and :dependent callbacks and their arities, custom
validators, error context, decoding and encoding wire data
	Data generation: Peri.generate/1, constraint-aware
generators, gen: overrides, property-based testing
	JSON Schema export: Peri.to_json_schema/1
	Ecto integration: changesets and custom Ecto types
	Phoenix integration: form and params bridging
	Schema refs: reusable named schemas via {:ref, ...}

Checks if the given data conforms to the specified schema.
Parameters
	schema: The schema definition to validate against.
	data: The data to be validated.

Options
	:mode - Validation mode. Can be :strict (default) or :permissive.	:strict - Only fields defined in the schema are returned.
	:permissive - All fields from the input data are preserved.



Returns
	true if the data conforms to the schema.
	false if the data does not conform to the schema.

Examples
iex> schema = %{name: :string, age: :integer}
iex> data = %{name: "Alice", age: 30}
iex> Peri.conforms?(schema, data)
true

iex> invalid_data = %{name: "Alice", age: "thirty"}
iex> Peri.conforms?(schema, invalid_data)
false

          @spec decode(schema(), data :: term(), keyword()) :: {:ok, term()} | {:error, term()}


      


Decodes wire data against a schema.
Coercion is a schema directive, so decoding is exactly validate/3:
{:coerce, source, target} fields convert their source representation
into the target type, and values already matching the target pass through
unchanged.
Accepts the same options as validate/3 and returns the same shape.
Examples
iex> schema = %{page: {:coerce, :string, :integer}}
iex> Peri.decode(schema, %{"page" => "2"})
{:ok, %{page: 2}}

iex> schema = %{page: {:coerce, :string, :integer}}
iex> Peri.decode(schema, %{page: 2})
{:ok, %{page: 2}}

Defines a schema with a given name and schema definition.
Examples
defmodule MySchemas do
  import Peri

  defschema :user, %{
    name: :string,
    age: :integer,
    email: {:required, :string}
  }

  # With permissive mode
  defschema :flexible_user, %{
    name: :string,
    email: {:required, :string}
  }, mode: :permissive

  # With metadata (field-level and schema-level)
  defschema :documented_user, %{
    email: {:meta, {:required, :string}, doc: "Login email", example: "a@b.io"}
  }, title: "User", description: "Account holder"
end

# Schema-level metadata is accessible via __schema_meta__/1:
MySchemas.__schema_meta__(:documented_user)
# => [title: "User", description: "Account holder"]

user_data = %{name: "John", age: 30, email: "john@example.com"}
MySchemas.user(user_data)
# => {:ok, %{name: "John", age: 30, email: "john@example.com"}}

invalid_data = %{name: "John", age: 30}
MySchemas.user(invalid_data)
# => {:error, [email: "is required"]}

# Permissive mode preserves extra fields
flexible_data = %{name: "John", email: "john@example.com", role: "admin"}
MySchemas.flexible_user(flexible_data)
# => {:ok, %{name: "John", email: "john@example.com", role: "admin"}}

          @spec encode(schema(), data :: term(), keyword()) :: {:ok, term()} | {:error, term()}


      


Encodes data against a schema, producing its wire representation.
Validates data against the schema (target types), then applies the
reverse of each codec directive:
	{:coerce, source, target} - built-in :string sources render with
to_string/1 (to_iso8601/1 for date/time structs); when the
encode: opt is given, that function/MFA is applied instead. Custom
function/MFA sources without an encode: opt pass the validated value
through unchanged.
	{type, {:encode, fun}} - applies fun (or MFA) to the validated
value. This directive is inert under validate/3 and decode/3.
	{:transform, fun} - skipped; transforms are decode-only.

Accepts the same options as validate/3 and returns the same shape.
Examples
iex> schema = %{page: {:coerce, :string, :integer}}
iex> Peri.encode(schema, %{page: 2})
{:ok, %{page: "2"}}

iex> schema = %{upcased: {:string, {:encode, &String.downcase/1}}}
iex> Peri.encode(schema, %{upcased: "HELLO"})
{:ok, %{upcased: "hello"}}

          @spec except(map_schema(), [atom() | String.t()]) ::
  {:ok, map_schema()} | {:error, [Peri.Error.t()]}


      


Drops the given top-level keys from a map schema.
Keys not present in the schema are ignored. The resulting schema is checked
with validate_schema/1, returning its error tuple when invalid.
Examples
iex> Peri.except(%{name: :string, age: :integer}, [:age])
{:ok, %{name: :string}}

iex> Peri.except(%{name: :string}, [:missing])
{:ok, %{name: :string}}

          @spec from_json_schema(map(), [opt]) :: {:ok, schema()} | {:error, term()}
when opt: {:keys, :strings | :atoms | :atoms!}


      


Decodes a JSON Schema (Draft 7) map into a Peri schema.
Returns {:ok, schema} if the resulting Peri schema is valid, otherwise
{:error, errors}.

Generates sample data based on the given schema definition using StreamData.
This function validates the schema first, and if the schema is valid, it uses the
Peri.Generatable.gen/1 function to generate data according to the schema.
Note that this function returns a Stream, so you traverse easily the data generations.
Parameters
	schema: The schema definition to generate data for.

Returns
	{:ok, stream} if the data is successfully generated.
	{:error, errors} if there are validation errors in the schema.

Examples
iex> schema = %{name: :string, age: {:integer, {:range, {18, 65}}}}
iex> {:ok, stream} = Peri.generate(schema)
iex> [data] = Enum.take(stream, 1)
iex> is_map(data)
true
iex> data[:age] in 18..65
true

        (macro)


        
          
        

    

  


  

Checks if the given data is an enumerable, specifically a map or a list.
Parameters
	data: The data to check.

Examples
iex> is_enumerable(%{})
true

iex> is_enumerable([])
true

iex> is_enumerable(123)
false

iex> is_enumerable("string")
false

Checks if the given data is a numeric value, specifically a integer or a float.
Parameters
	data: The data to check.

Examples
iex> is_numeric(123)
true

iex> is_numeric(0xFF)
true

iex> is_numeric(12.12)
true

iex> is_numeric("string")
false

iex> is_numeric(%{})
false

        (macro)


        
          
        

    

  


  

Checks if the given type as an atom is a numeric (integer or float).
Parameters
	data: The data to check.

Examples
iex> is_numeric(:integer)
true

iex> is_numeric(:float)
true

iex> is_numeric(:list)
false

iex> is_numeric({:enum, _})
false

          @spec merge(map_schema(), map_schema()) ::
  {:ok, map_schema()} | {:error, [Peri.Error.t()]}


      


Deep merges two map schemas into a new one.
When both schemas define the same key as a plain map (a nested schema), the
nested schemas are merged recursively. Otherwise the value from the right
side wins: type tuples and directives are never merged structurally.
The resulting schema is checked with validate_schema/1, returning its
error tuple when the composed schema is invalid.
Examples
iex> Peri.merge(%{name: :string}, %{age: :integer})
{:ok, %{name: :string, age: :integer}}

iex> Peri.merge(%{name: :string}, %{name: :atom})
{:ok, %{name: :atom}}

iex> Peri.merge(%{user: %{name: :string}}, %{user: %{age: :integer}})
{:ok, %{user: %{name: :string, age: :integer}}}

Helper function to put a value into an enum, handling
not only maps and keyword lists but also structs.
Examples
iex> Peri.put_in_enum(%{}, :hello, "world")
iex> Peri.put_in_enum(%{}, "hello", "world")
iex> Peri.put_in_enum(%User{}, :hello, "world")
iex> Peri.put_in_enum([], :hello, "world")

          @spec select(map_schema(), [atom() | String.t()]) ::
  {:ok, map_schema()} | {:error, [Peri.Error.t()]}


      


Keeps only the given top-level keys of a map schema.
Keys not present in the schema are ignored. The resulting schema is checked
with validate_schema/1, returning its error tuple when invalid.
Examples
iex> Peri.select(%{name: :string, age: :integer}, [:name])
{:ok, %{name: :string}}

iex> Peri.select(%{name: :string}, [:name, :missing])
{:ok, %{name: :string}}

          @spec to_changeset!(schema(), attrs :: map()) :: Ecto.Changeset.t()


      


Converts a Peri.schema() definition to an Ecto schemaless changesets.

          @spec to_json_schema(schema(), Peri.JSONSchema.Encoder.opts()) :: map()


      


Converts a Peri schema into a JSON Schema (Draft 7) map.
Reads {:meta, type, opts} annotations and emits title, description,
examples, deprecated. Dynamic types degrade per :on_unsupported
(:omit | :true_schema | :raise, default :omit).
Pass :exclude_meta_keys to drop annotation keywords from the output —
commonly [:default] when the consumer-facing schema should not surface
validation defaults.
Examples
iex> Peri.to_json_schema(%{name: {:required, :string}})
%{"type" => "object", "properties" => %{"name" => %{"type" => "string"}}, "required" => ["name"]}

iex> Peri.to_json_schema({:integer, {:default, 0}}, exclude_meta_keys: [:default])
%{"type" => "integer"}

Validates a given data map against a schema with options.
Returns {:ok, data} if the data is valid according to the schema, or {:error, errors} if there are validation errors.
Parameters
	schema: The schema definition map.
	data: The data map to be validated.
	opts: Options for validation.

Options
	:mode - Validation mode. Can be :strict (default) or :permissive.	:strict - Only fields defined in the schema are returned.
	:permissive - All fields from the input data are preserved.



Examples
schema = %{name: :string, age: :integer}
data = %{name: "John", age: 30, extra: "field"}

# Strict mode (default)
Peri.validate(schema, data)
# => {:ok, %{name: "John", age: 30}}

# Permissive mode
Peri.validate(schema, data, mode: :permissive)
# => {:ok, %{name: "John", age: 30, extra: "field"}}

Validates a schema definition to ensure it adheres to the expected structure and types.
This function can handle both simple and complex schema definitions, including nested schemas, custom validation functions, and various type constraints.
Parameters
	schema - The schema definition to be validated. It can be a map or a keyword list representing the schema.

Returns
	{:ok, schema} - If the schema is valid, returns the original schema.
	{:error, errors} - If the schema is invalid, returns an error tuple with detailed error information.

Examples
  Validating a simple schema:
  schema = %{
    name: :string,
    age: :integer,
    email: {:required, :string}
  }
  assert {:ok, ^schema} = validate_schema(schema)
  Validating a nested schema:
  schema = %{
    user: %{
      name: :string,
      profile: %{
        age: {:required, :integer},
        email: {:required, :string}
      }
    }
  }
  assert {:ok, ^schema} = validate_schema(schema)
  Handling invalid schema definition:
  schema = %{
    name: :str,
    age: :integer,
    email: {:required, :string}
  }
  assert {:error, _errors} = validate_schema(schema)

          @spec walk(schema(), Peri.Walker.walker_fun()) :: schema()


      


Depth-first rewrite of a schema tree.
The callback is invoked on every subtree (pre-order). It must return either
{:cont, new_node} to replace the node and continue, or :drop to remove it
(only valid for values inside a map or keyword schema).
Building block for transforms like "make every field optional" or "strip
internal-only fields from a public DTO". See Peri.Walker for details.
Examples
iex> schema = %{name: {:required, :string}, age: {:required, :integer}}
iex> Peri.walk(schema, fn
...>   {:required, t} -> {:cont, t}
...>   other -> {:cont, other}
...> end)
%{name: :string, age: :integer}

Responsible to convert between Peri <> Ecto types definitions

Represents any type. Passes data to Cassandra as is.

        Callback implementation for Ecto.Type.embed_as/1.

        Callback implementation for Ecto.Type.equal?/2.

Callback implementation for Ecto.Type.embed_as/1.

Callback implementation for Ecto.Type.equal?/2.

  


        

      


  

    
Peri.Ecto.Type.Atom 
    



      
Custom Ecto type for storing atoms as strings

      


      
        Summary


  
    Functions
  


    
      
        embed_as(_)

      


        Callback implementation for Ecto.Type.embed_as/1.



    


    
      
        equal?(term1, term2)

      


        Callback implementation for Ecto.Type.equal?/2.

Callback implementation for Ecto.Type.embed_as/1.

Callback implementation for Ecto.Type.equal?/2.

  


        

      


  

    
Peri.Ecto.Type.Either 
    



      
Custom Ecto type for storing either of two types

      




  

    
Peri.Ecto.Type.OneOf 
    



      
Custom Ecto type for storing one of many types, aka sum types

      




  

    
Peri.Ecto.Type.PID 
    



      
Custom Ecto type for storing PIDs, use with caution

        embed_as(_)

      


        Callback implementation for Ecto.Type.embed_as/1.



    


    
      
        equal?(term1, term2)

      


        Callback implementation for Ecto.Type.equal?/2.

Callback implementation for Ecto.Type.embed_as/1.

Callback implementation for Ecto.Type.equal?/2.

  


        

      


  

    
Peri.Ecto.Type.Tuple 
    



      
Custom Ecto type for storing tuples with multiple types/elements

      




  

    
Peri.Form 
    



      
A form-ready struct holding Peri validation results.
Peri.Phoenix.to_form/3 builds this struct from a schema and raw params,
and the Phoenix.HTML.FormData implementation (available when
phoenix_html is loaded) converts it into a Phoenix.HTML.Form, so
Peri schemas plug into Phoenix.Component.form/1 and <.input> without
Ecto.
Fields
	:schema - the Peri schema the params were validated against
	:data - the validated data (atom keys), %{} when validation failed
	:params - the raw params as received (usually string keys)
	:errors - errors in changeset format, %{field => [{message, opts}]}
with nested humanized maps under assoc keys (list entries keyed by index)
	:name - the form name, defaults to "peri"
	:action - the form action (:validate, :save, ...), used by
LiveView to decide when to show errors

          @type errors() :: %{optional(atom()) => [{String.t(), keyword()}] | errors()}

          @type t() :: %Peri.Form{
  action: atom() | nil,
  data: map(),
  errors: errors(),
  name: String.t() | nil,
  params: map(),
  schema: Peri.schema() | nil
}


      



  


        

      


  

    
Peri.Generatable 
    



      
A module for generating sample data based on Peri schemas using StreamData.
This module provides functions to generate various types of data, conforming to the schema definitions given in Peri. It leverages the StreamData library to create streams of random data that match the specified types and constraints.
Examples
iex> schema = %{
...>   name: :string,
...>   age: {:integer, {:gte, 18}},
...>   active: :boolean
...> }
iex> Peri.Generatable.gen(schema)
%StreamData{
  type: :fixed_map,
  data: %{name: StreamData.string(:alphanumeric), age: StreamData.filter(StreamData.integer(), &(&1 >= 18)), active: StreamData.boolean()}
}

        Generates a stream of data based on the given schema type.

Generates a stream of data based on the given schema type.
This function provides various clauses to handle different types and constraints defined in Peri schemas. It uses StreamData to generate streams of random data conforming to the specified types and constraints.
Parameters
	schema: The schema type to generate data for. It can be a simple type like :integer, :string, etc., or a complex type with constraints like {:integer, {:gte, 18}}.

Returns
	A StreamData generator stream for the specified schema type.

Examples
iex> Peri.Generatable.gen(:atom)
%StreamData{type: :atom, data: ...}

iex> Peri.Generatable.gen(:string)
%StreamData{type: :string, data: ...}

iex> Peri.Generatable.gen(:integer)
%StreamData{type: :integer, data: ...}

iex> Peri.Generatable.gen({:enum, [:admin, :user, :guest]})
%StreamData{type: :one_of, data: ...}

iex> Peri.Generatable.gen({:list, :integer})
%StreamData{type: :list_of, data: ...}

iex> Peri.Generatable.gen({:tuple, [:string, :integer]})
%StreamData{type: :tuple, data: ...}

iex> Peri.Generatable.gen({:integer, {:gt, 10}})
%StreamData{type: :filter, data: ...}

iex> Peri.Generatable.gen({:string, {:regex, ~r/^[a-z]+$/}})
%StreamData{type: :filter, data: ...}

iex> Peri.Generatable.gen({:either, {:integer, :string}})
%StreamData{type: :one_of, data: ...}

iex> Peri.Generatable.gen({:custom, {MyModule, :my_fun}})
%StreamData{type: :filter, data: ...}

iex> schema = %{name: :string, age: {:integer, {:gte, 18}}}
iex> Peri.Generatable.gen(schema)
%StreamData{type: :fixed_map, data: ...}

  


        

      


  

    
Peri.JSONSchema.Decoder 
    



      
Decodes a JSON Schema (Draft 7) map into a Peri schema definition.
Returns {:ok, schema} on success or {:error, errors} if the resulting
Peri schema fails Peri.validate_schema/1.
Prefer Peri.from_json_schema/1 as the public entry point.

          @spec decode(map(), [opt]) :: {:ok, Peri.schema()} | {:error, term()}
when opt: {:keys, :strings | :atoms | :atoms!}


      



  


        

      


  

    
Peri.JSONSchema.Encoder 
    



      
Encodes a Peri schema definition into a JSON Schema (Draft 7) map.
Field-level metadata attached via {:meta, type, opts} is read during
encoding and surfaced as JSON Schema annotation/format keywords. See
@meta_keys for the recognised vocabulary; unknown keys are dropped.
Dynamic Peri types (:dependent, :cond, :custom) cannot be expressed
statically. The :on_unsupported option controls the fallback:
	:omit (default) — emit %{} (true schema)
	:true_schema — same as :omit
	:raise — raise Peri.JSONSchema.Encoder.UnsupportedTypeError

The :exclude_meta_keys option drops listed annotation keywords from the
output. Accepts any subset of the meta vocabulary plus :default. Useful
when emitting consumer-facing JSON Schema where default values are
validation-only and should not be exposed.
Peri.to_json_schema(schema, exclude_meta_keys: [:default])
Prefer Peri.to_json_schema/2 as the public entry point.

          @type opts() :: [
  on_unsupported: :omit | :true_schema | :raise,
  exclude_meta_keys: [atom()]
]


      



  


        

      

      
        Functions


        


    

  
    
      
    
    
      encode(schema, opts \\ [])



        
          
        

    

  


  

      

          @spec encode(Peri.schema(), opts()) :: map()


      



  


        

      


  

    
Peri.Parser 
    



      
The Peri.Parser module is responsible for managing the state during schema validation. 
It centralizes functions to handle updating data, adding errors, and managing the path within 
the data structure being validated.
Struct
The Peri.Parser struct has the following fields:
	:data - The current state of the data being validated.
	:errors - A list of errors encountered during validation.
	:path - The current path within the data structure being validated.

        add_error(state, err)

      


        Adds an error to the parser state's list of errors.



    


    
      
        bump_ref_depth(state)

      


        Increments the ref-resolution depth counter. Used by {:ref, _}
directive resolution to bound recursion on cyclic data.



    


    
      
        for_field(parent, key, exists?)

      


    


    
      
        for_list_element(element_data, parent_parser, index)

      


        Creates a new parser for a list element, preserving the root data.



    


    
      
        new(data, list)

      


        Initializes a new Peri.Parser struct with the given data.



    


    
      
        update_data(state, key, val)

      


        Updates the data in the parser state at the given key with the specified value.

Adds an error to the parser state's list of errors.
Parameters
	state - The current Peri.Parser state.
	err - The %Peri.Error{} struct representing the error to add.

Examples
iex> state = Peri.Parser.new(%{name: "Alice"})
iex> error = %Peri.Error{path: [:name], message: "is required", content: []}
iex> Peri.Parser.add_error(state, error)
%Peri.Parser{data: %{name: "Alice"}, errors: [%Peri.Error{path: [:name], message: "is required", content: []}], path: []}

Increments the ref-resolution depth counter. Used by {:ref, _}
directive resolution to bound recursion on cyclic data.

      for_list_element(element_data, parent_parser, index)



        
          
        

    

  


  

Creates a new parser for a list element, preserving the root data.
Parameters
	element_data - The data for the current list element.
	parent_parser - The parent parser containing root data and path information.
	index - The index of the element in the list.

Examples
iex> parent = Peri.Parser.new(%{items: [1, 2, 3]}, root_data: %{items: [1, 2, 3]})
iex> Peri.Parser.for_list_element(1, parent, 0)
%Peri.Parser{data: 1, current_data: 1, root_data: %{items: [1, 2, 3]}, errors: [], path: [0]}

Initializes a new Peri.Parser struct with the given data.
Parameters
	data - The initial data to be validated.

Examples
iex> Peri.Parser.new(%{name: "Alice"})
%Peri.Parser{data: %{name: "Alice"}, errors: [], path: []}

Updates the data in the parser state at the given key with the specified value.
Parameters
	state - The current Peri.Parser state.
	key - The key to update in the data.
	val - The value to set at the specified key.

Examples
iex> state = Peri.Parser.new(%{name: "Alice"})
iex> Peri.Parser.update_data(state, :age, 30)
%Peri.Parser{data: %{name: "Alice", age: 30}, errors: [], path: []}

  


        

      


  

    
Peri.Phoenix 
    



      
Bridges Peri schemas and Phoenix forms.
Validates (and coerces) raw params with Peri.decode/3, wraps the
result in a Peri.Form struct, and converts it into a
Phoenix.HTML.Form through the Phoenix.HTML.FormData protocol, so
schemas plug directly into Phoenix.Component.form/1 and the <.input>
component without Ecto.
LiveView round trip
@schema %{
  name: {:required, :string},
  age: {:coerce, :string, {:integer, {:gte, 18}}}
}

def mount(_params, _session, socket) do
  {:ok, assign(socket, form: Peri.Phoenix.to_form(@schema))}
end

def handle_event("validate", %{"peri" => params}, socket) do
  {:noreply, assign(socket, form: Peri.Phoenix.to_form(@schema, params))}
end

def handle_event("save", %{"peri" => params}, socket) do
  case Peri.decode(@schema, params) do
    {:ok, data} -> # persist, redirect...
    {:error, _} -> {:noreply, assign(socket, form: Peri.Phoenix.to_form(@schema, params))}
  end
end
And in the template:
<.form for={@form} phx-change="validate" phx-submit="save">
  <.input field={@form[:name]} label="Name" />
  <.input field={@form[:age]} type="number" label="Age" />
</.form>

      


      
        Summary


  
    Functions
  


    
      
        to_form(schema_or_form, params \\ %{}, opts \\ [])

      


        Validates params against schema and returns a Phoenix.HTML.Form.

      to_form(schema_or_form, params \\ %{}, opts \\ [])



        
          
        

    

  


  

      

          @spec to_form(Peri.schema() | Peri.Form.t(), map(), keyword()) ::
  Phoenix.HTML.Form.t()


      


Validates params against schema and returns a Phoenix.HTML.Form.
Accepts the same options as Phoenix.HTML.FormData.to_form/2 (:as,
:id, :action, ...) plus :mode, which is forwarded to
Peri.decode/3 (:strict by default, :permissive to keep unknown
fields).
On success the form carries the validated data and no errors. On failure
errors are stored in changeset format (%{field => [{message, opts}]},
nested humanized maps under assoc keys) and the form action defaults to
:validate so LiveView shows the errors.
The first argument may also be an already built Peri.Form: with
non-empty params it revalidates against the stored schema (the update
path of a phx-change round trip); with no params it is converted as is.

  


        

      


  

    
Peri.Walker 
    



      
Depth-first schema rewriter.
Peri.walk/2 (delegated here) traverses a schema in pre-order, invoking the
supplied callback on every subtree. Callback contract depends on context:
	Map / keyword schema entries — invoked as {:field, key, value}.
Return one of:
	{:cont, {:field, new_key, new_value}} — replace the entry; the
walker recurses into new_value as a type expression. new_key may
differ from the original (rename) and may be any term valid as a key
for the surrounding container.
	:drop — remove the entry from the parent map / keyword list.


	Every other subtree — invoked as the type expression itself
(e.g. :string, {:list, …}, {:multi, …}, a nested map). Return:
	{:cont, new_node} — replace and continue walking children of
new_node.
	:drop — not allowed in this context; raises.



Map keys are not visited as standalone nodes; constraint option lists
(e.g. [gte: 18, error: "…"]), :enum members, :literal values, :ref
names, :multi tags, callbacks, and transforms are not visited either —
only sub-schemas and field entries are.
Example — make every required field optional:
Peri.walk(schema, fn
  {:required, t} -> {:cont, t}
  {:required, t, _opts} -> {:cont, t}
  other -> {:cont, other}
end)
Example — strip private fields from a map schema:
Peri.walk(schema, fn
  {:field, k, _v} when k in [:internal_id, :secret] -> :drop
  other -> {:cont, other}
end)
Example — rename email to :login:
Peri.walk(schema, fn
  {:field, :email, v} -> {:cont, {:field, :login, v}}
  other -> {:cont, other}
end)

          @type field_node() :: {:field, term(), term()}


      



  



  
    
      
    
    
      sentinel()



        
          
        

    

  


  

      

          @type sentinel() :: {:cont, term()} | {:cont, field_node()} | :drop

          @type walker_fun() :: (term() -> sentinel())

          @spec walk(Peri.schema(), walker_fun()) :: Peri.schema()


      



  


        

      


  

    
Peri.Error exception
    



      
Defines the structure and functions for handling validation errors in the Peri schema validation library.
The Peri.Error module encapsulates information about validation errors that occur during schema validation. Each error contains details about the path to the invalid data, the type of error, and any nested errors for complex or deeply nested schemas.
Attributes
	:message - A human-readable message describing the error.
	:content - Additional information about the error, such as expected and actual values.
	:path - A list representing the path to the invalid data within the structure being validated.
	:key - The specific key or field that caused the error.
	:errors - A list of nested Peri.Error structs for detailed information about nested validation errors.

Example
iex> error = %Peri.Error{
...>   message: "Validation failed",
...>   content: %{expected: :string, actual: :integer},
...>   path: [:user, :age],
...>   key: :age,
...>   errors: [
...>     %Peri.Error{
...>       message: "Expected type string, got integer",
...>       content: nil,
...>       path: [:user, :age],
...>       key: :age,
...>       errors: nil
...>     }
...>   ]
...> }
%Peri.Error{
  message: "Validation failed",
  content: %{expected: :string, actual: :integer},
  path: [:user, :age],
  key: :age,
  errors: [
    %Peri.Error{
      message: "Expected type string, got integer",
      content: nil,
      path: [:user, :age],
      key: :age,
      errors: nil
    }
  ]
}
Functions
	error_to_map/1 - Converts a Peri.Error struct to a map, including nested errors.

        error_to_map(err)

      


        Recursively converts a Peri.Error struct into a map.



    


    
      
        format_error_message(reason, context)

      


    


    
      
        humanize(errors)

      


        Converts an error or list of errors into a nested, data-shaped map of
messages, mirroring Ecto.Changeset.traverse_errors/2 output.



    


    
      
        new_child(path, key, message, context)

      


        Creates a new child error with a path, key, message, and context.



    


    
      
        new_parent(path, key, errors)

      


        Creates a new parent error with nested errors.



    


    
      
        new_single(message, context)

      


        Creates a new single error with a formatted message and context.



    


    
      
        summarize(type)

      


        Produces a compact, human-friendly string for a schema or type definition.



    


    
      
        traverse_errors(errors, fun)

      


        Recursively walks an error or list of errors, applying the callback to each
leaf and replacing its message with the callback's return value.

          @type t() :: %Peri.Error{
  __exception__: term(),
  content: keyword(),
  errors: [t()] | nil,
  key: atom() | nil,
  message: String.t(),
  path: [atom()]
}

Recursively converts a Peri.Error struct into a map.
Parameters
	error - A Peri.Error struct to be transformed.

Examples
iex> error = %Peri.Error{
...>   message: "Validation failed",
...>   content: %{expected: :string, actual: :integer},
...>   path: [:user, :age],
...>   key: :age,
...>   errors: [
...>     %Peri.Error{
...>       message: "Expected type string, got integer",
...>       content: nil,
...>       path: [:user, :age],
...>       key: :age,
...>       errors: nil
...>     }
...>   ]
...> }
iex> Peri.Error.error_to_map(error)
%{
  message: "Validation failed",
  content: %{expected: :string, actual: :integer},
  path: [:user, :age],
  key: :age,
  errors: [
    %{
      message: "Expected type string, got integer",
      content: nil,
      path: [:user, :age],
      key: :age,
      errors: nil
    }
  ]
}

          @spec humanize(t() | [t()]) ::
  %{optional(atom() | integer() | binary()) => [String.t()] | map()}
  | [String.t()]


      


Converts an error or list of errors into a nested, data-shaped map of
messages, mirroring Ecto.Changeset.traverse_errors/2 output.
Each leaf error (one without nested errors) contributes its message
under its path. Integer path segments become integer keys (list
indices), atoms stay atoms and binaries stay binaries. Multiple leaf
errors at the same path append to the message list.
Leaf errors without a path arise from Peri.Error.new_single/2, which is
how top-level scalar validations report failure
(Peri.validate(:string, 5)). Since there is no field to nest them
under, they humanize to a bare list of messages instead of a map.
Because humanize/1 reads each leaf's final message verbatim, it
composes with traverse_errors/2: translate first, then humanize.
Examples
iex> errors = [
...>   %Peri.Error{path: [:addresses], key: :addresses, errors: [
...>     %Peri.Error{path: [:addresses, 0, :street], key: :street, message: "is too short"}
...>   ]},
...>   %Peri.Error{path: [:email], key: :email, message: "is required"}
...> ]
iex> Peri.Error.humanize(errors)
%{addresses: %{0 => %{street: ["is too short"]}}, email: ["is required"]}

iex> Peri.Error.humanize(%Peri.Error{message: "expected type of :string received 5 value"})
["expected type of :string received 5 value"]

iex> Peri.Error.humanize([])
%{}

  



  
    
      
    
    
      new_child(path, key, message, context)



        
          
        

    

  


  

Creates a new child error with a path, key, message, and context.
Parameters
	path - A list representing the path to the invalid data.
	key - The specific key or field that caused the error.
	message - A string template for the error message.
	context - A list of key-value pairs to replace in the message template.

Examples
iex> Peri.Error.new_child([:user], :age, "Invalid value for %{field}", [field: "age"])
%Peri.Error{
  path: [:user, :age],
  key: :age,
  message: "Invalid value for age",
  content: %{field: "age"}
}

Creates a new parent error with nested errors.
Parameters
	path - A list representing the path to the invalid data.
	key - The specific key or field that caused the error.
	errors - A list of nested Peri.Error structs.

Examples
iex> Peri.Error.new_parent([:user], :age, [%Peri.Error{message: "Invalid age"}])
%Peri.Error{
  path: [:user, :age],
  key: :age,
  errors: [%Peri.Error{message: "Invalid age"}]
}

Creates a new single error with a formatted message and context.
Parameters
	message - A string template for the error message.
	context - A list of key-value pairs to replace in the message template.

Examples
iex> Peri.Error.new_single("Invalid value for %{field}", [field: "age"])
%Peri.Error{
  message: "Invalid value for age",
  content: %{field: "age"}
}

          @spec summarize(term()) :: String.t()


      


Produces a compact, human-friendly string for a schema or type definition.
Used in error messages to avoid dumping the entire schema (which can be huge
for deeply nested or polymorphic schemas). Named schemas
({:schema, _, name: "..."}) render as their name; raw maps render as a
sorted key list (%{keys: [:a, :b, ...]}) truncated past 6 entries.

          @spec traverse_errors([t()] | t(), (t() -> String.t() | term())) :: [t()] | t()


      


Recursively walks an error or list of errors, applying the callback to each
leaf and replacing its message with the callback's return value.
Mirrors Ecto.Changeset.traverse_errors/2. Useful for translating template
strings into user-facing locale messages, e.g.
Peri.Error.traverse_errors(errors, fn err ->
  Gettext.dgettext(MyAppWeb.Gettext, "errors", err.message, err.content || %{})
end)
Returns the same error shape with translated messages. Non-string callback
results are coerced via to_string/1.

Peri.InvalidSchema exception
    



      
Exception raised when an invalid schema is encountered.
This exception is raised with a list of Peri.Error structs,
providing a readable message overview of the validation errors.

          @type t() :: %Peri.InvalidSchema{
  __exception__: term(),
  errors: [Peri.Error.t()],
  message: String.t()
}


      



  


        

      


  OEBPS/dist/epub-4WIP524F.js
(()=>{var s=document.querySelector.bind(document),o=document.querySelectorAll.bind(document);function r(e){document.readyState!=="loading"?e():document.addEventListener("DOMContentLoaded",e)}var l="hll";window.addEventListener("exdoc:loaded",t);function t(){o("[data-group-id]").forEach(e=>{e.addEventListener("mouseenter",i),e.addEventListener("mouseleave",i)})}function i(e){let n=e.currentTarget,a=e.type==="mouseenter",c=n.getAttribute("data-group-id");n.parentElement.querySelectorAll(`[data-group-id="${c}"]`).forEach(u=>{u.classList.toggle(l,a)})}r(()=>{t()});})();




